2 files changed, 42 insertions, 0 deletions
diff --git a/deps/v8/build/toolchain/fuchsia/BUILD.gn b/deps/v8/build/toolchain/fuchsia/BUILD.gn
new file mode 100644
index 0000000000..06ac5e5b74
--- /dev/null
+++ b/deps/v8/build/toolchain/fuchsia/BUILD.gn
@@ -0,0 +1,41 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/fuchsia/config.gni")
+import("//build/toolchain/gcc_toolchain.gni")
+
+# Fuchsia builds using the Clang toolchain, with most parameters common across
+# the different target architectures.
+template("fuchsia_clang_toolchain") {
+  clang_toolchain(target_name) {
+    assert(host_os == "linux" || host_os == "mac")
+    assert(defined(invoker.toolchain_args),
+           "toolchain_args must be defined for fuchsia_clang_toolchain()")
+
+    # We want to build and strip binaries, but retain the unstripped binaries
+    # in runtime_deps to make them available for isolates.
+    if (host_os == "linux") {
+      strip = rebase_path("//buildtools/third_party/eu-strip/bin/eu-strip",
+                          root_build_dir)
+      use_unstripped_as_runtime_outputs = true
+    }
+
+    default_shlib_subdir = "/lib"
+
+    toolchain_args = invoker.toolchain_args
+    toolchain_args.current_os = "fuchsia"
+  }
+}
+
+fuchsia_clang_toolchain("x64") {
+  toolchain_args = {
+    current_cpu = "x64"
+  }
+}
+
+fuchsia_clang_toolchain("arm64") {
+  toolchain_args = {
+    current_cpu = "arm64"
+  }
+}
diff --git a/deps/v8/build/toolchain/fuchsia/OWNERS b/deps/v8/build/toolchain/fuchsia/OWNERS
new file mode 100644
index 0000000000..3f809e82b1
--- /dev/null
+++ b/deps/v8/build/toolchain/fuchsia/OWNERS
@@ -0,0 +1 @@
+scottmg@chromium.org