Move v8/build into this repository.

Since we need to patch some files, we don't let depot_tools
manage these files anymore.

build.git commit a0b2e3b2708bcf81ec00ac1738b586bcc5e04eea

1 files changed, 50 insertions, 0 deletions

diff --git a/deps/v8/build/config/zip.gni b/deps/v8/build/config/zip.gni
new file mode 100644
index 0000000000..58cb692f71
--- /dev/null
+++ b/deps/v8/build/config/zip.gni
@@ -0,0 +1,50 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("python.gni")
+
+# Creates a zip archive of the inputs.
+#
+# output (required)
+#     Path to output zip.
+# inputs (required)
+#     List of input files to zip.
+# base_dir (optional)
+#     If provided, the archive paths will be relative to this directory.
+#     Applies only to |inputs|.
+#
+# deps, public_deps, data, data_deps, testonly, visibility
+#     Normal meaning.
+template("zip") {
+  action_with_pydeps(target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "data",
+                             "data_deps",
+                             "deps",
+                             "public_deps",
+                             "testonly",
+                             "visibility",
+                           ])
+    script = "//build/android/gyp/zip.py"
+    inputs = invoker.inputs
+    outputs = [
+      invoker.output,
+    ]
+
+    args = [
+      "--output",
+      rebase_path(invoker.output, root_build_dir),
+    ]
+
+    _rebased_inputs = rebase_path(invoker.inputs, root_build_dir)
+    args += [ "--input-files=$_rebased_inputs" ]
+    if (defined(invoker.base_dir)) {
+      args += [
+        "--input-files-base-dir",
+        rebase_path(invoker.base_dir, root_build_dir),
+      ]
+    }
+  }
+}