commit 570828490dc085fe93c5bedeadadcd3bec2786c1
parent 75e146f54c85643e782f6807e1f3c0dc8660c3c2
Author: Florian Dold <florian@dold.me>
Date: Tue, 12 May 2026 18:00:37 +0200
remove autotools leftovers
Diffstat:
| D | Makefile.am | | | 22 | ---------------------- |
| D | configure.ac | | | 334 | ------------------------------------------------------------------------------- |
2 files changed, 0 insertions(+), 356 deletions(-)
diff --git a/Makefile.am b/Makefile.am
@@ -1,22 +0,0 @@
-# This Makefile is in the public domain
-
-if DOC_ONLY
-if ENABLE_DOC
- SUBDIRS = . contrib doc
-else
- SUBDIRS = . contrib
-endif
-else
-if ENABLE_DOC
- SUBDIRS = . src contrib doc
-else
- SUBDIRS = . src contrib
-endif
-endif
-
-@DX_RULES@
-
-ACLOCAL_AMFLAGS = -I m4
-EXTRA_DIST = \
- AUTHORS \
- COPYING.AGPL
diff --git a/configure.ac b/configure.ac
@@ -1,334 +0,0 @@
-# -*- Autoconf -*-
-# Process this file with autoconf to produce a configure script.
-#
-# This configure file is in the public domain
-
-AC_PREREQ([2.69])
-AC_INIT([challenger],[1.5.1],[taler-bug@gnu.org])
-AC_CONFIG_SRCDIR([src/challenger/challenger-httpd.c])
-AC_CONFIG_HEADERS([challenger_config.h])
-# support for non-recursive builds
-AM_INIT_AUTOMAKE([subdir-objects 1.9 tar-pax])
-
-# pretty build rules
-AM_SILENT_RULES([yes])
-
-AC_CONFIG_MACRO_DIR([m4])
-AC_PROG_AWK
-AC_PROG_CC
-AC_PROG_OBJC
-AC_PROG_INSTALL
-AC_PROG_LN_S
-AC_PROG_MAKE_SET
-AM_PROG_CC_C_O
-
-LT_INIT([disable-static])
-
-
-DX_INIT_DOXYGEN([challenger],,,
-DX_PS_FEATURE(OFF),
-DX_PDF_FEATURE(OFF),
-DX_RTF_FEATURE(OFF),
-DX_CHI_FEATURE(OFF),
-DX_XML_FEATURE(OFF))
-
-
-AC_CHECK_PROG([DPKG_ARCH], [dpkg-architecture], [yes], [no])
-if test "x$DPKG_ARCH" = "xyes"; then
- MULTIARCH=`dpkg-architecture -qDEB_HOST_MULTIARCH`
-else
- MULTIARCH=""
-fi
-
-AC_MSG_CHECKING([whether to compile documentation ONLY])
-AC_ARG_ENABLE([only-doc],
- [AS_HELP_STRING([--enable-only-doc], [only compile Challenger documentation])],
- [doc_only=${enableval}],
- [doc_only=no])
-AC_MSG_RESULT($doc_only)
-AM_CONDITIONAL([DOC_ONLY], [test "$doc_only" = "yes"])
-
-
-# Not indented as it covers most of the file...
-AS_IF([test "x$doc_only" != xyes],[
-
-# Force some CFLAGS
-CFLAGS="-Wall -Wno-address-of-packed-member $CFLAGS"
-
-# Checks for header files.
-AC_CHECK_HEADERS([stdint.h stdlib.h string.h unistd.h])
-
-
-# Check for GNUnet's libgnunetutil.
-libgnunetutil=0
-AC_MSG_CHECKING([for libgnunetutil])
-AC_ARG_WITH(gnunet,
- [AS_HELP_STRING([--with-gnunet=PFX], [base of GNUnet installation])],
- [AC_MSG_RESULT([given as $with_gnunet])],
- [AC_MSG_RESULT(not given)
- with_gnunet=yes])
-AS_CASE([$with_gnunet],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-gnunet is required])],
- [LDFLAGS="-L$with_gnunet/lib/$MULTIARCH -L$with_gnunet/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_gnunet/include $CPPFLAGS"])
-AC_CHECK_HEADERS([gnunet/gnunet_util_lib.h],
- [AC_CHECK_LIB([gnunetutil], [GNUNET_SCHEDULER_run], libgnunetutil=1)])
-AS_IF([test $libgnunetutil != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libgnunetutil to build this program.
-*** This library is part of GNUnet, available at
-*** https://gnunet.org
-*** ]])])
-
-
-# test for postgres
-AX_LIB_POSTGRESQL([14])
-AS_IF([test "x$found_postgresql" = "xyes"],[postgres=true])
-AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
-
-SYNC_LIB_LDFLAGS="-export-dynamic -no-undefined"
-SYNC_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
-
-AC_SUBST(SYNC_LIB_LDFLAGS)
-AC_SUBST(SYNC_PLUGIN_LDFLAGS)
-
-# Check for Taler's libtalerpq
-libtalerpq=0
-AC_MSG_CHECKING([for libtalerpq])
-AC_ARG_WITH(exchange,
- [AS_HELP_STRING([--with-exchange=PFX], [base of Taler EXCHANGE installation])],
- [AC_MSG_RESULT([given as $with_exchange])],
- [AC_MSG_RESULT(not given)
- with_exchange=yes])
-AS_CASE([$with_exchange],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-exchange is required])],
- [LDFLAGS="-L$with_exchange/lib/$MULTIARCH -L$with_exchange/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_exchange/include $CPPFLAGS $POSTGRESQL_CPPFLAGS"])
-
-CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
-
-AC_CHECK_HEADERS([gnunet/gnunet_pq_lib.h],
- [AC_CHECK_LIB([gnunetpq], [GNUNET_PQ_connect_with_cfg], libgnunetpq=1)])
-AM_CONDITIONAL(HAVE_GNUNETPQ, test x$libgnunetpq = x1)
-
-
-libtalermhd=0
-AC_MSG_CHECKING([for libtalermhd])
-AC_ARG_WITH(exchange,
- [AS_HELP_STRING([--with-exchange=PFX], [base of Taler EXCHANGE installation])],
- [AC_MSG_RESULT([given as $with_exchange])],
- [AC_MSG_RESULT(not given)
- with_exchange=yes])
-AS_CASE([$with_exchange],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-exchange is required])],
- [LDFLAGS="-L$with_exchange/lib/$MULTIARCH -L$with_exchange/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_exchange/include $CPPFLAGS $POSTGRESQL_CPPFLAGS"])
-
-AC_CHECK_HEADERS([taler/taler_mhd_lib.h],
- [AC_CHECK_LIB([talermhd], [TALER_MHD_listen_bind], libtalermhd=1)])
-AM_CONDITIONAL(HAVE_TALERMHD, test x$libtalermhd = x1)
-AS_IF([test $libtalermhd != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libtalermhd >= 1.1.0 (API v6) to build this program.
-*** This library is part of the GNU Taler exchange, available at
-*** https://taler.net
-*** ]])])
-
-libtalertemplating=0
-AC_CHECK_HEADERS([taler/taler_templating_lib.h],
- [AC_CHECK_LIB([talertemplating], [TALER_TEMPLATING_fill2], libtalertemplating=1)])
-AM_CONDITIONAL(HAVE_TALERTEMPLATING, test x$libtalertemplating = x1)
-AS_IF([test $libtalertemplating != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libtalertemplating >= 0.14.6 to build this program.
-*** This library is part of the GNU Taler exchange, available at
-*** https://taler.net
-*** ]])])
-
-
-# check for libmicrohttpd
-microhttpd=0
-AC_MSG_CHECKING([for microhttpd])
-AC_ARG_WITH([microhttpd],
- [AS_HELP_STRING([--with-microhttpd=PFX], [base of microhttpd installation])],
- [AC_MSG_RESULT([given as $with_microhttpd])],
- [AC_MSG_RESULT([not given])
- with_microhttpd=yes])
-AS_CASE([$with_microhttpd],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-microhttpd is required])],
- [LDFLAGS="-L$with_microhttpd/lib/$MULTIARCH -L$with_microhttpd/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"])
-AC_CHECK_LIB(microhttpd,MHD_start_daemon,
- [AC_CHECK_HEADER([microhttpd.h],[microhttpd=1])])
-AS_IF([test $microhttpd = 0],
- [AC_MSG_ERROR([[
-***
-*** You need libmicrohttpd to build this program.
-*** ]])])
-
-jansson=0
-PKG_CHECK_MODULES([JANSSON], [jansson >= 2.3],
- [LDFLAGS="$JANSSON_LIBS $LDFLAGS"
- CPPFLAGS="$JANSSON_CFLAGS $CPPFLAGS"],
- [AC_MSG_ERROR([[
-***
-*** You need libjansson to build this program.
-***]])])
-
-# Save before checking libcurl
-CFLAGS_SAVE=$CFLAGS
-LDFLAGS_SAVE=$LDFLAGS
-LIBS_SAVE=$LIBS
-
-# libcurl-gnutls
-LIBCURL_CHECK_CONFIG(,7.34.0,[curl=1],[curl=0])
-
-# cURL must support CURLINFO_TLS_SESSION, version >= 7.34
-AS_IF([test "x$curl" = x1],[
- AC_CHECK_HEADER([curl/curl.h],
- [AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=1],[curl=0],[[#include <curl/curl.h>]])],
- [curl=0])
-])
-
-# libcurl should be mutually exclusive
-AS_IF([test "$curl" = 1],
- AM_CONDITIONAL(HAVE_LIBCURL, true)
- AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])
- [LIBCURL_LIBS="-lcurl"],
- [AC_MSG_ERROR([FATAL: No libcurl])])
-
-AC_SUBST([LIBCURL_LIBS])
-
-
-# Check for GNUnet's libgnunetcurl.
-libgnunetcurl=0
-AC_MSG_CHECKING([for libgnunetcurl])
-AC_ARG_WITH(gnunet,
- [AS_HELP_STRING([--with-gnunet=PFX], [base of GNUnet installation])],
- [AC_MSG_RESULT([given as $with_gnunet])],
- [AC_MSG_RESULT(not given)
- with_gnunet=yes])
-AS_CASE([$with_gnunet],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-gnunet is required])],
- [LDFLAGS="-L$with_gnunet/lib/$MULTIARCH -L$with_gnunet/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_gnunet/include $CPPFLAGS"])
-AC_CHECK_HEADERS([gnunet/gnunet_curl_lib.h],
- [AC_CHECK_LIB([gnunetcurl], [GNUNET_CURL_get_select_info], libgnunetcurl=1)])
-AS_IF([test $libgnunetcurl != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libgnunetcurl to build this program.
-*** Make sure you have libcurl installed while
-*** building GNUnet.
-*** ]])])
-
-# Restore after curl checks messed up these values
-CFLAGS=$CFLAGS_SAVE
-LDFLAGS=$LDFLAGS_SAVE
-LIBS=$LIBS_SAVE
-
-
-# gcov compilation
-AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
-AC_ARG_ENABLE([coverage],
- AS_HELP_STRING([--enable-coverage],
- [compile the library with code coverage support]),
- [use_gcov=${enableval}],
- [use_gcov=no])
-AC_MSG_RESULT($use_gcov)
-AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
-
-# Require minimum libgcrypt version
-need_libgcrypt_version=1.6.1
-AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], ["$need_libgcrypt_version"],
- [minimum version of libgcrypt required])
-AM_PATH_LIBGCRYPT([$need_libgcrypt_version])
-
-# logging
-extra_logging=0
-AC_ARG_ENABLE([logging],
- AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose ('yes' is the default)]),
- [AS_IF([test "x$enableval" = "xyes"], [],
- [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
- [test "x$enableval" = "xverbose"], [extra_logging=1]
- [test "x$enableval" = "xveryverbose"], [extra_logging=2])
- ], [])
-AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
-
-# version info
-AC_PATH_PROG(gitcommand, git)
-AC_MSG_CHECKING(for source being under a VCS)
-git_version=
-AS_IF([test ! "X$gitcommand" = "X"],
-[
- git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
-])
-AS_IF([test "X$git_version" = "X"],
- [
- vcs_name="no"
- vcs_version="\"release\""
- ],
- [
- vcs_name="yes, git-svn"
- vcs_version="\"git-$git_version\""
- ])
-AC_MSG_RESULT($vcs_name)
-
-AC_MSG_CHECKING(VCS version)
-AC_MSG_RESULT($vcs_version)
-AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
-
-# Checks for typedefs, structures, and compiler characteristics.
-AC_TYPE_PID_T
-AC_TYPE_SIZE_T
-AC_TYPE_UINT16_T
-AC_TYPE_UINT32_T
-AC_TYPE_UINT64_T
-AC_TYPE_INTMAX_T
-AC_TYPE_UINTMAX_T
-
-# Checks for library functions.
-AC_CHECK_FUNCS([strdup])
-
-
-AC_ARG_ENABLE([[doc]],
- [AS_HELP_STRING([[--disable-doc]], [do not build any documentation])], ,
- [enable_doc=yes])
-test "x$enable_doc" = "xno" || enable_doc=yes
-AM_CONDITIONAL([ENABLE_DOC], [test "x$enable_doc" = "xyes"])
-
-
-],[ # this is about the doc-only if on top of the file
-
-# logic if doc_only is set, make sure conditionals are still defined
-AM_CONDITIONAL([HAVE_GNUNETPQ], [false])
-AM_CONDITIONAL([HAVE_POSTGRESQL], [false])
-AM_CONDITIONAL([HAVE_LIBCURL], [false])
-AM_CONDITIONAL([USE_COVERAGE], [false])
-AM_CONDITIONAL([ENABLE_DOC], [true])
-AM_CONDITIONAL(HAVE_TALERMHD, [false])
-AM_CONDITIONAL(HAVE_TALERTEMPLATING, [false])
-
-# end of 'doc_only'
-])
-
-
-AC_CONFIG_FILES([Makefile
-contrib/Makefile
-doc/Makefile
-doc/doxygen/Makefile
-src/Makefile
-src/include/Makefile
-src/util/Makefile
-src/challengerdb/Makefile
-src/challenger/Makefile
-])
-AC_OUTPUT
