quickjs-tart

quickjs-based runtime for wallet-core logic
Log | Files | Refs | README | LICENSE

curl-config.cmake.in (2679B)

      1 #***************************************************************************
      2 #                                  _   _ ____  _
      3 #  Project                     ___| | | |  _ \| |
      4 #                             / __| | | | |_) | |
      5 #                            | (__| |_| |  _ <| |___
      6 #                             \___|\___/|_| \_\_____|
      7 #
      8 # Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
      9 #
     10 # This software is licensed as described in the file COPYING, which
     11 # you should have received as part of this distribution. The terms
     12 # are also available at https://curl.se/docs/copyright.html.
     13 #
     14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
     15 # copies of the Software, and permit persons to whom the Software is
     16 # furnished to do so, under the terms of the COPYING file.
     17 #
     18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
     19 # KIND, either express or implied.
     20 #
     21 # SPDX-License-Identifier: curl
     22 #
     23 ###########################################################################
     24 @PACKAGE_INIT@
     25 
     26 include(CMakeFindDependencyMacro)
     27 if("@USE_OPENSSL@")
     28   if("@OPENSSL_VERSION_MAJOR@")
     29     find_dependency(OpenSSL "@OPENSSL_VERSION_MAJOR@")
     30   else()
     31     find_dependency(OpenSSL)
     32   endif()
     33 endif()
     34 if("@HAVE_LIBZ@")
     35   find_dependency(ZLIB "@ZLIB_VERSION_MAJOR@")
     36 endif()
     37 
     38 include("${CMAKE_CURRENT_LIST_DIR}/@TARGETS_EXPORT_NAME@.cmake")
     39 
     40 # Alias for either shared or static library
     41 if(NOT TARGET @PROJECT_NAME@::@LIB_NAME@)
     42   if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.11 AND CMAKE_VERSION VERSION_LESS 3.18)
     43     set_target_properties(@PROJECT_NAME@::@LIB_SELECTED@ PROPERTIES IMPORTED_GLOBAL TRUE)
     44   endif()
     45   add_library(@PROJECT_NAME@::@LIB_NAME@ ALIAS @PROJECT_NAME@::@LIB_SELECTED@)
     46 endif()
     47 
     48 # For compatibility with CMake's FindCURL.cmake
     49 set(CURL_VERSION_STRING "@CURLVERSION@")
     50 set(CURL_LIBRARIES @PROJECT_NAME@::@LIB_NAME@)
     51 set_and_check(CURL_INCLUDE_DIRS "@PACKAGE_CMAKE_INSTALL_INCLUDEDIR@")
     52 
     53 set(CURL_SUPPORTED_PROTOCOLS "@CURL_SUPPORTED_PROTOCOLS_LIST@")
     54 set(CURL_SUPPORTED_FEATURES "@CURL_SUPPORTED_FEATURES_LIST@")
     55 
     56 foreach(_item IN LISTS CURL_SUPPORTED_PROTOCOLS CURL_SUPPORTED_FEATURES)
     57   set(CURL_SUPPORTS_${_item} TRUE)
     58 endforeach()
     59 
     60 set(_missing_req "")
     61 foreach(_item IN LISTS CURL_FIND_COMPONENTS)
     62   if(CURL_SUPPORTS_${_item})
     63     set(CURL_${_item}_FOUND TRUE)
     64   elseif(CURL_FIND_REQUIRED_${_item})
     65     list(APPEND _missing_req ${_item})
     66   endif()
     67 endforeach()
     68 
     69 if(_missing_req)
     70   string(REPLACE ";" " " _missing_req "${_missing_req}")
     71   if(CURL_FIND_REQUIRED)
     72     message(FATAL_ERROR "CURL: missing required components: ${_missing_req}")
     73   endif()
     74   unset(_missing_req)
     75 endif()
     76 
     77 check_required_components("@PROJECT_NAME@")