quickjs-tart

quickjs-based runtime for wallet-core logic
Log | Files | Refs | README | LICENSE

FindNGHTTP2.cmake (3035B)

      1 #***************************************************************************
      2 #                                  _   _ ____  _
      3 #  Project                     ___| | | |  _ \| |
      4 #                             / __| | | | |_) | |
      5 #                            | (__| |_| |  _ <| |___
      6 #                             \___|\___/|_| \_\_____|
      7 #
      8 # Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
      9 #
     10 # This software is licensed as described in the file COPYING, which
     11 # you should have received as part of this distribution. The terms
     12 # are also available at https://curl.se/docs/copyright.html.
     13 #
     14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
     15 # copies of the Software, and permit persons to whom the Software is
     16 # furnished to do so, under the terms of the COPYING file.
     17 #
     18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
     19 # KIND, either express or implied.
     20 #
     21 # SPDX-License-Identifier: curl
     22 #
     23 ###########################################################################
     24 # Find the nghttp2 library
     25 #
     26 # Input variables:
     27 #
     28 # - `NGHTTP2_INCLUDE_DIR`:   The nghttp2 include directory.
     29 # - `NGHTTP2_LIBRARY`:       Path to `nghttp2` library.
     30 #
     31 # Result variables:
     32 #
     33 # - `NGHTTP2_FOUND`:         System has nghttp2.
     34 # - `NGHTTP2_INCLUDE_DIRS`:  The nghttp2 include directories.
     35 # - `NGHTTP2_LIBRARIES`:     The nghttp2 library names.
     36 # - `NGHTTP2_LIBRARY_DIRS`:  The nghttp2 library directories.
     37 # - `NGHTTP2_PC_REQUIRES`:   The nghttp2 pkg-config packages.
     38 # - `NGHTTP2_CFLAGS`:        Required compiler flags.
     39 # - `NGHTTP2_VERSION`:       Version of nghttp2.
     40 
     41 set(NGHTTP2_PC_REQUIRES "libnghttp2")
     42 
     43 if(CURL_USE_PKGCONFIG AND
     44    NOT DEFINED NGHTTP2_INCLUDE_DIR AND
     45    NOT DEFINED NGHTTP2_LIBRARY)
     46   find_package(PkgConfig QUIET)
     47   pkg_check_modules(NGHTTP2 ${NGHTTP2_PC_REQUIRES})
     48 endif()
     49 
     50 if(NGHTTP2_FOUND)
     51   string(REPLACE ";" " " NGHTTP2_CFLAGS "${NGHTTP2_CFLAGS}")
     52   message(STATUS "Found NGHTTP2 (via pkg-config): ${NGHTTP2_INCLUDE_DIRS} (found version \"${NGHTTP2_VERSION}\")")
     53 else()
     54   find_path(NGHTTP2_INCLUDE_DIR NAMES "nghttp2/nghttp2.h")
     55   find_library(NGHTTP2_LIBRARY NAMES "nghttp2" "nghttp2_static")
     56 
     57   unset(NGHTTP2_VERSION CACHE)
     58   if(NGHTTP2_INCLUDE_DIR AND EXISTS "${NGHTTP2_INCLUDE_DIR}/nghttp2/nghttp2ver.h")
     59     set(_version_regex "#[\t ]*define[\t ]+NGHTTP2_VERSION[\t ]+\"([^\"]*)\"")
     60     file(STRINGS "${NGHTTP2_INCLUDE_DIR}/nghttp2/nghttp2ver.h" _version_str REGEX "${_version_regex}")
     61     string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
     62     set(NGHTTP2_VERSION "${_version_str}")
     63     unset(_version_regex)
     64     unset(_version_str)
     65   endif()
     66 
     67   include(FindPackageHandleStandardArgs)
     68   find_package_handle_standard_args(NGHTTP2
     69     REQUIRED_VARS
     70       NGHTTP2_INCLUDE_DIR
     71       NGHTTP2_LIBRARY
     72     VERSION_VAR
     73       NGHTTP2_VERSION
     74   )
     75 
     76   if(NGHTTP2_FOUND)
     77     set(NGHTTP2_INCLUDE_DIRS ${NGHTTP2_INCLUDE_DIR})
     78     set(NGHTTP2_LIBRARIES    ${NGHTTP2_LIBRARY})
     79   endif()
     80 
     81   mark_as_advanced(NGHTTP2_INCLUDE_DIR NGHTTP2_LIBRARY)
     82 endif()