quickjs-tart

quickjs-based runtime for wallet-core logic
Log | Files | Refs | README | LICENSE

FindMSH3.cmake (2440B)

      1 #***************************************************************************
      2 #                                  _   _ ____  _
      3 #  Project                     ___| | | |  _ \| |
      4 #                             / __| | | | |_) | |
      5 #                            | (__| |_| |  _ <| |___
      6 #                             \___|\___/|_| \_\_____|
      7 #
      8 # Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
      9 #
     10 # This software is licensed as described in the file COPYING, which
     11 # you should have received as part of this distribution. The terms
     12 # are also available at https://curl.se/docs/copyright.html.
     13 #
     14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
     15 # copies of the Software, and permit persons to whom the Software is
     16 # furnished to do so, under the terms of the COPYING file.
     17 #
     18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
     19 # KIND, either express or implied.
     20 #
     21 # SPDX-License-Identifier: curl
     22 #
     23 ###########################################################################
     24 # Find the msh3 library
     25 #
     26 # Input variables:
     27 #
     28 # - `MSH3_INCLUDE_DIR`:   The msh3 include directory.
     29 # - `MSH3_LIBRARY`:       Path to `msh3` library.
     30 #
     31 # Result variables:
     32 #
     33 # - `MSH3_FOUND`:         System has msh3.
     34 # - `MSH3_INCLUDE_DIRS`:  The msh3 include directories.
     35 # - `MSH3_LIBRARIES`:     The msh3 library names.
     36 # - `MSH3_LIBRARY_DIRS`:  The msh3 library directories.
     37 # - `MSH3_PC_REQUIRES`:   The msh3 pkg-config packages.
     38 # - `MSH3_CFLAGS`:        Required compiler flags.
     39 # - `MSH3_VERSION`:       Version of msh3.
     40 
     41 set(MSH3_PC_REQUIRES "libmsh3")
     42 
     43 if(CURL_USE_PKGCONFIG AND
     44    NOT DEFINED MSH3_INCLUDE_DIR AND
     45    NOT DEFINED MSH3_LIBRARY)
     46   find_package(PkgConfig QUIET)
     47   pkg_check_modules(MSH3 ${MSH3_PC_REQUIRES})
     48 endif()
     49 
     50 if(MSH3_FOUND)
     51   string(REPLACE ";" " " MSH3_CFLAGS "${MSH3_CFLAGS}")
     52   message(STATUS "Found MSH3 (via pkg-config): ${MSH3_INCLUDE_DIRS} (found version \"${MSH3_VERSION}\")")
     53 else()
     54   set(MSH3_PC_REQUIRES "")  # Depend on pkg-config only when found via pkg-config
     55 
     56   find_path(MSH3_INCLUDE_DIR NAMES "msh3.h")
     57   find_library(MSH3_LIBRARY NAMES "msh3")
     58 
     59   include(FindPackageHandleStandardArgs)
     60   find_package_handle_standard_args(MSH3
     61     REQUIRED_VARS
     62       MSH3_INCLUDE_DIR
     63       MSH3_LIBRARY
     64   )
     65 
     66   if(MSH3_FOUND)
     67     set(MSH3_INCLUDE_DIRS ${MSH3_INCLUDE_DIR})
     68     set(MSH3_LIBRARIES    ${MSH3_LIBRARY})
     69   endif()
     70 
     71   mark_as_advanced(MSH3_INCLUDE_DIR MSH3_LIBRARY)
     72 endif()