summaryrefslogtreecommitdiff
path: root/wallet/build.gradle
blob: 55fda26c28ae552131c386f1be4f68558681f1b0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
/*
 * This file is part of GNU Taler
 * (C) 2020 Taler Systems S.A.
 *
 * GNU Taler is free software; you can redistribute it and/or modify it under the
 * terms of the GNU General Public License as published by the Free Software
 * Foundation; either version 3, or (at your option) any later version.
 *
 * GNU Taler is distributed in the hope that it will be useful, but WITHOUT ANY
 * WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
 * A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License along with
 * GNU Taler; see the file COPYING.  If not, see <http://www.gnu.org/licenses/>
 */

import com.android.build.gradle.tasks.MergeResources

plugins {
    id "com.android.application"
    id "kotlin-android"
    id "kotlinx-serialization"
    id "de.undercouch.download"
}

def walletCoreVersion = "v0.8.0"
def walletCoreSha256 = "46b0ec59e95f2621c8483f975dac9e288851c1e5809f386b49c491e52f41a190"

static def versionCodeEpoch() {
    return (new Date().getTime() / 1000).toInteger()
}
def gitCommit = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'rev-parse', '--short=7', 'HEAD'
        standardOutput = stdout
    }
    return stdout.toString().trim()
}

android {
    compileSdkVersion 30
    //noinspection GradleDependency
    buildToolsVersion "$build_tools_version"

    defaultConfig {
        applicationId "net.taler.wallet"
        minSdkVersion 21
        targetSdkVersion 30
        versionCode 9
        versionName "v0.8.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        buildConfigField "String", "WALLET_CORE_VERSION", "\"$walletCoreVersion\""
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
        debug {
            minifyEnabled minify_debug
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    flavorDimensions "distributionChannel"
    productFlavors {
        fdroid {
            dimension "distributionChannel"
            applicationIdSuffix ".fdroid"
        }
        google {
            dimension "distributionChannel"
        }
        nightly {
            dimension "distributionChannel"
            applicationIdSuffix ".nightly"
            versionCode versionCodeEpoch()
            versionNameSuffix " ($gitCommit)"
        }
    }

    compileOptions {
        sourceCompatibility = 1.8
        targetCompatibility = 1.8

        // Flag to enable support for the new language APIs for zxing
        coreLibraryDesugaringEnabled true
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }

    buildFeatures {
        viewBinding = true
    }

    packagingOptions {
        exclude("META-INF/*.kotlin_module")
    }

    lintOptions {
        abortOnError true
        ignoreWarnings false
        // TODO remove once com.google.android.material fixed this
        //      https://github.com/material-components/material-components-android/issues/504
        ignore "WrongConstant"
    }
}

dependencies {
    implementation project(":taler-kotlin-android")
    implementation project(":anastasis-ui")
    implementation 'net.taler:akono:0.1'

    implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"

    implementation 'androidx.preference:preference-ktx:1.1.1'
    implementation "com.google.android.material:material:$material_version"
    implementation "androidx.constraintlayout:constraintlayout:$constraintlayout_version"

    // Lists and Selection
    implementation "androidx.recyclerview:recyclerview:1.1.0"
    implementation "androidx.recyclerview:recyclerview-selection:1.1.0"

    // Navigation Library
    implementation "androidx.navigation:navigation-fragment-ktx:$nav_version"
    implementation "androidx.navigation:navigation-ui-ktx:$nav_version"

    // ViewModel and LiveData
    implementation "androidx.lifecycle:lifecycle-livedata-ktx:$lifecycle_version"

    // QR codes
    implementation 'com.journeyapps:zxing-android-embedded:4.0.2@aar'
    // needed to support zxing library in taler-kotlin-android on API < 24
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:1.1.1'

    // Nicer ProgressBar
    implementation 'me.zhanghai.android.materialprogressbar:library:1.6.1'

    // Markdown rendering
    final def markwon_version = '4.6.0'
    implementation "io.noties.markwon:core:$markwon_version"
    implementation "io.noties.markwon:ext-tables:$markwon_version"
    implementation "io.noties.markwon:recycler:$markwon_version"

    testImplementation "junit:junit:$junit_version"
    testImplementation 'org.json:json:20200518'
    androidTestImplementation 'androidx.test:runner:1.3.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.3.0'
}

def walletLibraryDir = "src/main/assets"
def walletDestFile = "${walletLibraryDir}/taler-wallet-android-${walletCoreVersion}.js"
task downloadWalletLibrary(type: Download, dependsOn: preBuild) {
    src "https://git.taler.net/wallet-core.git/plain/${walletCoreVersion}/taler-wallet-android.js?h=prebuilt"
    dest walletDestFile
    onlyIfModified true
    overwrite false
    doFirst {
        new File(walletLibraryDir).mkdirs()
        if (!file(dest).exists()) {  // delete old versions before fetching new one
            delete fileTree(walletLibraryDir) {
                include 'taler-wallet-android-*.js'
            }
        }
    }
}
task verifyWalletLibrary(type: Verify, dependsOn: downloadWalletLibrary) {
    src walletDestFile
    algorithm 'SHA-256'
    checksum walletCoreSha256
}
tasks.withType(MergeResources) {
    inputs.dir walletLibraryDir
    dependsOn verifyWalletLibrary
}